10 POKE53280,0:POKE53281,6:V=53248
15 PRINT"[147]                [218]EICHENDEMO             "
20 PRINT"[196]IESES [208]ROGRAMM ENTHAELT 5 [196]EMOPROGRAM-"
30 PRINT"ME ZUM [199]RAFIK-[203]URS [212]EIL 6."
40 PRINT"[210]UFEN [211]IE DIESE AUS DEM NUN FOLGENDEN"
45 PRINT"[205]ENU GANZ EINFACH AUF."
50 PRINT"[213]LI [194]ASTERS."
60 PRINT"                          [212]ASTE DRUECKEN"
70 GETA$:IFA$=""THEN70
80 :
90 REM *************
91 REM * HAUPTMENU *
92 REM *************
100 PRINT"[147]                [218]EICHENDEMO             "
110 PRINT"[194]ITTE WAEHLEN [211]IE:"
120 PRINT"------------------"
130 PRINT" 1 [146] - [205]ULICOLORZEICHENDEMO"
140 PRINT" 2 [146] - [197]XTENDED-[194]ACKGROUND-[195]OLOR-[196]EMO"
150 PRINT" 3 [146] - [214]ERTIKALSCROLL"
170 PRINT" 4 [146] - [194]ILDSCHIRMWACKELN"
180 PRINT" 5 [146] - [208]ROGRAMMENDE"
190 GETA$:IFA$=""THEN190
200 A=ASC(A$)-48:IFA<1ORA>5THEN190
205 IFA=5THENSYS64738
210 ONAGOSUB300,400,500,600
220 GOTO100
230 :
290 REM *****************
291 REM * MUTICOLORDEMO *
292 REM *****************
300 PRINT"[147]             [205]ULTICOLORDEMO             "
305 FORI=0TO1
310 PRINT"[196]IESE [196]EMO ZEIGT, WIE UNTERSCHIEDLICH"
320 PRINT"EIN [218]EICHENSATZ IM [205]ULTICOLORMODUS DAR-"
330 PRINT"GESTELLT WERDEN KANN."
340 NEXT
350 POKEV+22,PEEK(V+22)OR16:POKEV+35,0:POKEV+34,7
360 FORI=55816TO55916:POKEI,9:NEXT
370 PRINT"                          [212]ASTE DRUECKEN"
380 GETA$:IFA$=""THEN380
385 POKE53270,200
390 RETURN
391 :
392 REM ************
393 REM * EBC-DEMO *
394 REM ************
400 PRINT"[147]     EXTENDED-BACKGROUND-COLOR-DEMO     ";CHR$(142)
410 PRINT"DIESE DEMO ZEIGT, WIE VERSCHIEDEN DIE"
420 PRINT"ZEICHEN IM EXTENDED-BACKGROUND-COLOR-"
430 PRINT"MODUS DES 64ERS ERSCHEINEN KOENNEN..."
440 POKEV+17,PEEK(V+17)OR64
450 POKEV+34,11:POKEV+35,12:POKEV+36,15
460 FORI=0TO255:POKE1744+I,I:NEXT
470 PRINT"                          TASTE DRUECKEN"
480 GETA$:IFA$=""THEN480
485 POKEV+17,PEEK(V+17)ANDNOT64
490 RETURN
491 :
492 REM ******************
493 REM * VERTIKALSCROLL *
494 REM ******************
500 PRINT"[147]            [214]ERTIKALSCROLLDEMO          "
510 PRINT"   [196]AS IST EINE [211]CROLLDEMO. [196]ER [194]ILD-"
520 PRINT"   SCHIRM BEWEGT SICH GANZ WEICH NACH"
530 PRINT"   LINKS UND NACH RECHTS"
550 PRINT"             [212]ASTE DRUECKEN"
560 POKEV+22,PEEK(V+22)AND NOT 8
565 Q=PEEK(V+22)
570 FORI=7TO0STEP-1:POKEV+22,Q+I:FORZ=0TO50:NEXTZ:NEXTI
580 FORI=1TO7:POKEV+22,Q+I:FORZ=0TO50:NEXTZ:NEXTI
585 GETA$:IFA$<>""THENPOKEV+17,27:RETURN
590 GOTO570
591 :
592 REM *********************
593 REM * BILDSCHIRMWACKELN *
594 REM *********************
600 PRINT"[147]            [194]ILDSCHIRMWACKELN           "
610 PRINT"[196]IESER [215]ACKELEFFEKT KANN GUT IN"
620 PRINT"[211]PIELEN BEI [197]XPLOSIONEN EINGESETZT"
630 PRINT"WERDEN."
640 PRINT"             [212]ASTE DRUECKEN"
650 P=PEEK(V+17)-4:Q=PEEK(V+22)
660 A=INT(7*RND(1))+1:B=INT(7*RND(1))+1
670 POKEV+17,P+A:POKEV+22,Q+B
675 GETA$:IFA$<>""THENPOKEV+17,27:POKEV+22,8:RETURN
680 GOTO660